Merge pull request #80328 from etcwilde/ewilde/stdlib-string-processing

etcwilde · web-flow · commit ecc90933a26a · 2025-03-27T15:06:47.000-07:00
[CMake] [Stdlib] Build StringProcessing with new stdlib build
diff --git a/CMakeLists.txt b/CMakeLists.txt
@@ -1630,7 +1630,7 @@ if(SWIFT_ENABLE_NEW_RUNTIME_BUILD)
 
         DEPENDS PopulateRuntimeSourceDir
         CMAKE_ARGS
-          -DCMAKE_INSTALL_LIBDIR:FILEPATH=lib/swift/${SWIFT_SDK_${sdk}_LIB_SUBDIR}/${arch}
+          -DCMAKE_INSTALL_LIBDIR:FILEPATH=lib
           # Compiler will see mismatched swift modules and fail initial checks
           -DCMAKE_Swift_COMPILER_WORKS:BOOLEAN=YES
           -DBUILD_SHARED_LIBS:BOOLEAN=YES # TODO: Make this configurable
@@ -1646,12 +1646,32 @@ if(SWIFT_ENABLE_NEW_RUNTIME_BUILD)
           -DCMAKE_CXX_COMPILER_TARGET:STRING=${stdlib_target_triple}
           -DCMAKE_COLOR_DIAGNOSTICS:BOOLEAN=${CMAKE_COLOR_DIAGNOSTICS}
           -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
-          -DSwiftCore_PLATFORM_SUBDIR=${SWIFT_SDK_${sdk}_LIB_SUBDIR}
-          -DSwiftCore_ARCH_SUBDIR=${arch}
+          -DSwiftCore_INSTALL_NESTED_SUBDIR=YES
           -DSwiftCore_ENABLE_CONCURRENCY=YES)
       if(NOT ${CMAKE_CROSSCOMPILING})
-        add_dependencies("${stdlib_target}" swift-frontend)
+        add_dependencies("${stdlib_target}-core" swift-frontend)
       endif()
+
+      ExternalProject_Get_Property("${stdlib_target}-core" INSTALL_DIR)
+
+      ExternalProject_Add("${stdlib_target}-StringProcessing"
+        SOURCE_DIR
+          "${CMAKE_CURRENT_SOURCE_DIR}/Runtimes/Supplemental/StringProcessing"
+        DEPENDS "${stdlib_target}-core"
+        INSTALL_DIR "${INSTALL_DIR}"
+        INSTALL_COMMAND "" # No install story set up yet
+        CMAKE_ARGS
+          -DBUILD_SHARED_LIBS=YES
+          -DCMAKE_BUILD_TYPE:STRING=${CMAKE_BUILD_TYPE}
+          -DCMAKE_INSTALL_PREFIX:FILEPATH=${INSTALL_DIR}
+          -DCMAKE_Swift_COMPILER:FILEPATH=$<IF:$<BOOL:${CMAKE_CROSSCOMPILING}>,${CMAKE_Swift_COMPILER},$<PATH:REPLACE_FILENAME,$<TARGET_FILE:swift-frontend>,swiftc>>
+          -DCMAKE_C_COMPILER:FILEPATH=${CMAKE_C_COMPILER}
+          -DCMAKE_CXX_COMPILER:FILEPATH=${CMAKE_CXX_COMPILER}
+          -DCMAKE_Swift_COMPILER_TARGET:STRING=${stdlib_target_triple}
+          -DCMAKE_C_COMPILER_TARGET:STRING=${stdlib_target_triple}
+          -DCMAKE_CXX_COMPILER_TARGET:STRING=${stdlib_target_triple}
+          -DCMAKE_COLOR_DIAGNOSTICS:BOOLEAN=${CMAKE_COLOR_DIAGNOSTICS}
+          -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM})
     endforeach()
   endforeach()
 endif()
diff --git a/Runtimes/Core/CMakeLists.txt b/Runtimes/Core/CMakeLists.txt
@@ -225,12 +225,12 @@ install(EXPORT SwiftCoreTargets
   COMPONENT SwiftCore_cmake)
 include(CMakePackageConfigHelpers)
 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/interface/SwiftCoreConfig.cmake.in"
-  "${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCoreConfig.cmake"
+  "${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCore/SwiftCoreConfig.cmake"
   INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/SwiftCore")
-write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCoreConfigVersion.cmake"
+write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCore/SwiftCoreConfigVersion.cmake"
   VERSION "${PROJECT_VERSION}"
   COMPATIBILITY ExactVersion)
 install(FILES
-  "${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCoreConfig.cmake"
-  "${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCoreConfigVersion.cmake"
+  "${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCore/SwiftCoreConfig.cmake"
+  "${CMAKE_CURRENT_BINARY_DIR}/cmake/SwiftCore/SwiftCoreConfigVersion.cmake"
   DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/SwiftCore")
diff --git a/Runtimes/Core/cmake/interface/SwiftCoreConfig.cmake.in b/Runtimes/Core/cmake/interface/SwiftCoreConfig.cmake.in
@@ -1,5 +1,5 @@
 @PACKAGE_INIT@
-include("${CMAKE_CURRENT_LIST_DIR}/SwiftCore/SwiftCoreTargets.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/SwiftCoreTargets.cmake")
 
 set(SwiftCore_ENABLE_LIBRARY_EVOLUTION @SwiftCore_ENABLE_LIBRARY_EVOLUTION@)
 
diff --git a/Runtimes/Resync.cmake b/Runtimes/Resync.cmake
@@ -127,3 +127,22 @@ copy_files(public/Platform Overlay/Windows/CRT
 
 # TODO: Add source directories for the platform overlays, supplemental
 # libraries, and test support libraries.
+
+# Supplemental Libraries
+
+# Copy StringProcessing, RegexParser, RegexBuilder
+if(NOT DEFINED StringProcessing_ROOT_DIR)
+  find_path(StringProcessing_ROOT_DIR
+    "swift-experimental-string-processing/Package.swift"
+    HINTS "${CMAKE_CURRENT_LIST_DIR}/../../")
+endif()
+message(STATUS "String Processing Root: ${StringProcessing_ROOT_DIR}")
+
+copy_library_sources(_RegexParser "Sources" "Supplemental/StringProcessing"
+  ROOT "${StringProcessing_ROOT_DIR}/swift-experimental-string-processing")
+copy_library_sources(_StringProcessing "Sources" "Supplemental/StringProcessing"
+  ROOT "${StringProcessing_ROOT_DIR}/swift-experimental-string-processing")
+copy_library_sources(_CUnicode "Sources" "Supplemental/StringProcessing/_StringProcessing"
+  ROOT "${StringProcessing_ROOT_DIR}/swift-experimental-string-processing")
+copy_library_sources(RegexBuilder "Sources" "Supplemental/StringProcessing"
+  ROOT "${StringProcessing_ROOT_DIR}/swift-experimental-string-processing")
diff --git a/Runtimes/Supplemental/StringProcessing/CMakeLists.txt b/Runtimes/Supplemental/StringProcessing/CMakeLists.txt
@@ -0,0 +1,34 @@
+cmake_minimum_required(VERSION 3.29)
+
+set(CMAKE_POSITION_INDEPENDENT_CODE YES)
+
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/../cmake/modules")
+
+if($ENV{BUILD_NUMBER})
+  math(EXPR BUILD_NUMBER "$ENV{BUILD_NUMBER} % 65535")
+  set(BUILD_NUMBER ".${BUILD_NUMBER}")
+endif()
+project(SwiftStringProcessing
+  LANGUAGES Swift C
+  VERSION 6.1.0${BUILD_NUMBER})
+
+if(NOT PROJECT_IS_TOP_LEVEL)
+  message(FATAL_ERROR "Swift StringProcessing must build as a standalone project")
+endif()
+
+set(${PROJECT_NAME}_SWIFTC_SOURCE_DIR
+  "${PROJECT_SOURCE_DIR}/../../../"
+  CACHE FILEPATH "Path to the root source directory of the Swift compiler")
+
+find_package(SwiftCore)
+
+include(AvailabilityMacros)
+
+add_compile_options(
+  $<$<COMPILE_LANGUAGE:Swift>:-explicit-module-build>
+  $<$<COMPILE_LANGUAGE:Swift>:-nostdlibimport>
+  "$<$<COMPILE_LANGUAGE:Swift>:SHELL:-Xfrontend -disable-implicit-string-processing-module-import>")
+
+add_subdirectory(_RegexParser)
+add_subdirectory(_StringProcessing)
+add_subdirectory(RegexBuilder)
diff --git a/Runtimes/Supplemental/StringProcessing/RegexBuilder/CMakeLists.txt b/Runtimes/Supplemental/StringProcessing/RegexBuilder/CMakeLists.txt
@@ -0,0 +1,14 @@
+add_library(swiftRegexBuilder
+  CharacterClass.swift
+  Anchor.swift
+  Builder.swift
+  Algorithms.swift
+  Variadics.swift
+  DSL.swift)
+
+set_target_properties(swiftRegexBuilder PROPERTIES
+  Swift_MODULE_NAME RegexBuilder)
+
+target_link_libraries(swiftRegexBuilder PRIVATE
+  swift_StringProcessing
+  swiftCore)
diff --git a/Runtimes/Supplemental/StringProcessing/_RegexParser/CMakeLists.txt b/Runtimes/Supplemental/StringProcessing/_RegexParser/CMakeLists.txt
@@ -0,0 +1,37 @@
+add_library(swift_RegexParser
+  Regex/TreeProtocols.swift
+  Regex/Parse/DelimiterLexing.swift
+  Regex/Parse/Source.swift
+  Regex/Parse/CharacterPropertyClassification.swift
+  Regex/Parse/LexicalAnalysis.swift
+  Regex/Parse/SyntaxOptions.swift
+  Regex/Parse/CaptureList.swift
+  Regex/Parse/CompilerInterface.swift
+  Regex/Parse/CaptureStructure.swift
+  Regex/Parse/Parse.swift
+  Regex/Parse/SourceLocation.swift
+  Regex/Parse/Diagnostics.swift
+  Regex/Parse/Sema.swift
+  Regex/Printing/RenderRanges.swift
+  Regex/Printing/PrettyPrinter.swift
+  Regex/Printing/PrintAsCanonical.swift
+  Regex/Printing/DumpAST.swift
+  Regex/AST/ASTAction.swift
+  Regex/AST/AST.swift
+  Regex/AST/CustomCharClass.swift
+  Regex/AST/Quantification.swift
+  Regex/AST/Conditional.swift
+  Regex/AST/MatchingOptions.swift
+  Regex/AST/ASTProtocols.swift
+  Regex/AST/Group.swift
+  Regex/AST/Atom.swift
+  Utility/TypeConstruction.swift
+  Utility/Misc.swift
+  Utility/AllScalars.swift
+  Utility/Errors.swift
+  Utility/MissingUnicode.swift)
+
+target_link_libraries(swift_RegexParser PRIVATE swiftCore)
+
+set_target_properties(swift_RegexParser PROPERTIES
+  Swift_MODULE_NAME _RegexParser)
diff --git a/Runtimes/Supplemental/StringProcessing/_StringProcessing/CMakeLists.txt b/Runtimes/Supplemental/StringProcessing/_StringProcessing/CMakeLists.txt
@@ -0,0 +1,80 @@
+add_library(swift_StringProcessing
+  _CUnicode/UnicodeData.c
+  _CUnicode/UnicodeScalarProps.c
+  _CharacterClassModel.swift
+  Executor.swift
+  Capture.swift
+  Unicode/NumberParsing.swift
+  Unicode/ASCII.swift
+  Unicode/CharacterProps.swift
+  Unicode/Transcoding.swift
+  Unicode/ScalarProps.swift
+  Unicode/Comparison.swift
+  Unicode/NecessaryEvils.swift
+  Unicode/Validation.swift
+  Unicode/UCD.swift
+  Unicode/NFC.swift
+  Unicode/Encodings.swift
+  Unicode/Formatting.swift
+  Unicode/WordBreaking.swift
+  Unicode/Decoding.swift
+  Unicode/CaseConversion.swift
+  Algorithms/Matching/FirstMatch.swift
+  Algorithms/Matching/MatchingCollectionSearcher.swift
+  Algorithms/Matching/MatchResult.swift
+  Algorithms/Matching/MatchReplace.swift
+  Algorithms/Matching/Matches.swift
+  Algorithms/Algorithms/FirstRange.swift
+  Algorithms/Algorithms/Contains.swift
+  Algorithms/Algorithms/Split.swift
+  Algorithms/Algorithms/Trim.swift
+  Algorithms/Algorithms/Ranges.swift
+  Algorithms/Algorithms/StartsWith.swift
+  Algorithms/Algorithms/Replace.swift
+  Algorithms/Algorithms/SubstringSearcher.swift
+  Algorithms/Searchers/CollectionSearcher.swift
+  Algorithms/Searchers/ZSearcher.swift
+  Algorithms/Consumers/CollectionConsumer.swift
+  Algorithms/Consumers/FixedPatternConsumer.swift
+  Regex/Options.swift
+  Regex/Match.swift
+  Regex/CustomComponents.swift
+  Regex/Core.swift
+  Regex/ASTConversion.swift
+  Regex/DSLTree.swift
+  Regex/AnyRegexOutput.swift
+  LiteralPrinter.swift
+  MatchingOptions.swift
+  Compiler.swift
+  ConsumerInterface.swift
+  PrintAsPattern.swift
+  Engine/MEBuiltins.swift
+  Engine/Processor.swift
+  Engine/MEProgram.swift
+  Engine/MEQuantify.swift
+  Engine/InstPayload.swift
+  Engine/Backtracking.swift
+  Engine/Instruction.swift
+  Engine/Registers.swift
+  Engine/MEBuilder.swift
+  Engine/Structuralize.swift
+  Engine/Tracing.swift
+  Engine/Metrics.swift
+  Engine/MECapture.swift
+  ByteCodeGen.swift
+  Utility/AsciiBitset.swift
+  Utility/Traced.swift
+  Utility/TypedIndex.swift
+  Utility/Misc.swift
+  Utility/TypedInt.swift
+  Utility/Protocols.swift
+  Utility/TypeVerification.swift
+  Utility/RegexFactory.swift
+  Utility/ASTBuilder.swift)
+
+set_target_properties(swift_StringProcessing PROPERTIES
+  Swift_MODULE_NAME _StringProcessing)
+
+target_link_libraries(swift_StringProcessing PRIVATE
+    swift_RegexParser
+    swiftCore)
diff --git a/Runtimes/Supplemental/cmake/modules/AvailabilityMacros.cmake b/Runtimes/Supplemental/cmake/modules/AvailabilityMacros.cmake
@@ -0,0 +1,5 @@
+file(STRINGS "${${PROJECT_NAME}_SWIFTC_SOURCE_DIR}/utils/availability-macros.def" availability_defs)
+list(FILTER availability_defs EXCLUDE REGEX "^\\s*(#.*)?$")
+foreach(def ${availability_defs})
+  add_compile_options("$<$<COMPILE_LANGUAGE:Swift>:SHELL:-Xfrontend -define-availability -Xfrontend \"${def}\">")
+endforeach()
