ccinfo: when providing ccinfo, optionally include libstd and alloc

The new attribute on RustToolchain is the label of a target that
provides __rust_realloc et al, which allows ld(1) to use the .rlib
files directly without needing to involve rustc in the linking
step. This means Rust and C++ can be mixed in a cc_binary freely
without needing any staticlib-type crates, which avoids problems if
you have a cc_binary -> rust_library -> cc_library -> rust_library
situation.

Author: durin42

rust/private/rustc.bzl

@@ -693,6 +693,9 @@ def establish_cc_info(ctx, crate_info, toolchain, cc_toolchain, feature_configur
         if CcInfo in dep:
             cc_infos.append(dep[CcInfo])
 
+    if crate_info.type in ("rlib", "lib") and toolchain.extra_libstd_and_allocator_ccinfo:
+        cc_infos.append(toolchain.extra_libstd_and_allocator_ccinfo)
+
     return [cc_common.merge_cc_infos(cc_infos = cc_infos)]
 
 def add_edition_flags(args, crate):

rust/toolchain.bzl

@@ -1,5 +1,15 @@
 """The rust_toolchain rule definition and implementation."""
 
+load(
+    "//rust/private:utils.bzl",
+    "find_cc_toolchain",
+)
+
+def _make_dota(ctx, f):
+    dot_a = ctx.actions.declare_file(f.basename + ".a", sibling = f)
+    ctx.actions.symlink(output = dot_a, target_file = f)
+    return dot_a
+
 def _rust_toolchain_impl(ctx):
     """The rust_toolchain implementation
 
@@ -17,6 +27,42 @@ def _rust_toolchain_impl(ctx):
     for k, v in ctx.attr.debug_info.items():
         if not k in ctx.attr.opt_level:
             fail("Compilation mode {} is not defined in opt_level but is defined debug_info".format(k))
+    link_inputs = []
+    std_rlibs = [f for f in ctx.attr.rust_lib.files.to_list() if f.basename.endswith(".rlib")]
+    cc_toolchain, feature_configuration = find_cc_toolchain(ctx)
+    if std_rlibs:
+        link_inputs.append(cc_common.create_linker_input(
+            owner = ctx.attr.rust_lib.label,
+            libraries = depset(
+                [
+                    cc_common.create_library_to_link(
+                        # TODO(augie): wat? this needs no actions
+                        actions = ctx.actions,
+                        feature_configuration = feature_configuration,
+                        cc_toolchain = cc_toolchain,
+                        static_library = _make_dota(ctx, f),
+                    )
+                    for f in std_rlibs
+                ],
+            ),
+        ))
+    if ctx.attr.allocator_library:
+        link_inputs.append(cc_common.create_linker_input(
+            owner = ctx.attr.allocator_library.allocator_library.label,
+            libraries = depset([
+                cc_common.create_library_to_link(
+                    # TODO(augie): wat? this needs no actions
+                    actions = ctx.actions,
+                    feature_configuration = feature_configuration,
+                    cc_toolchain = cc_toolchain,
+                    static_library = f,
+                )
+                for f in ctx.attr.allocator_library.files.to_list()
+            ]),
+        ))
+    extra_libstd_and_allocator_ccinfo = None
+    if link_inputs:
+        extra_libstd_and_allocator_ccinfo = CcInfo(linking_context = cc_common.create_linking_context(linker_inputs = depset(link_inputs)))
 
     toolchain = platform_common.ToolchainInfo(
         rustc = ctx.file.rustc,
@@ -38,11 +84,13 @@ def _rust_toolchain_impl(ctx):
         default_edition = ctx.attr.default_edition,
         compilation_mode_opts = compilation_mode_opts,
         crosstool_files = ctx.files._crosstool,
+        extra_libstd_and_allocator_ccinfo = extra_libstd_and_allocator_ccinfo,
     )
     return [toolchain]
 
 rust_toolchain = rule(
     implementation = _rust_toolchain_impl,
+    fragments = ["cpp"],
     attrs = {
         "binary_ext": attr.string(
             doc = "The extension for binaries created from rustc.",
@@ -131,6 +179,12 @@ rust_toolchain = rule(
         "_crosstool": attr.label(
             default = Label("@bazel_tools//tools/cpp:current_cc_toolchain"),
         ),
+        "_cc_toolchain": attr.label(
+            default = "@bazel_tools//tools/cpp:current_cc_toolchain",
+        ),
+        "allocator_library": attr.label(
+            doc = "Target that provides allocator functions when rust_library targets are embedded in a cc_binary.",
+        ),
     },
     doc = """Declares a Rust toolchain for use.
 

test/unit/cc_info/cc_info_test.bzl

@@ -6,11 +6,11 @@ load("//rust:defs.bzl", "rust_binary", "rust_library", "rust_proc_macro", "rust_
 def _is_dylib_on_windows(ctx):
     return ctx.target_platform_has_constraint(ctx.attr._windows[platform_common.ConstraintValueInfo])
 
-def _assert_cc_info_has_library_to_link(env, tut, type):
+def _assert_cc_info_has_library_to_link(env, tut, type, ccinfo_count):
     asserts.true(env, CcInfo in tut, "rust_library should provide CcInfo")
     cc_info = tut[CcInfo]
     linker_inputs = cc_info.linking_context.linker_inputs.to_list()
-    asserts.equals(env, len(linker_inputs), 1)
+    asserts.equals(env, len(linker_inputs), ccinfo_count)
     library_to_link = linker_inputs[0].libraries[0]
     asserts.equals(env, False, library_to_link.alwayslink)
 
@@ -42,7 +42,7 @@ def _assert_cc_info_has_library_to_link(env, tut, type):
 def _rlib_provides_cc_info_test_impl(ctx):
     env = analysistest.begin(ctx)
     tut = analysistest.target_under_test(env)
-    _assert_cc_info_has_library_to_link(env, tut, "rlib")
+    _assert_cc_info_has_library_to_link(env, tut, "rlib", 2)
     return analysistest.end(env)
 
 def _bin_does_not_provide_cc_info_test_impl(ctx):
@@ -60,13 +60,13 @@ def _proc_macro_does_not_provide_cc_info_test_impl(ctx):
 def _cdylib_provides_cc_info_test_impl(ctx):
     env = analysistest.begin(ctx)
     tut = analysistest.target_under_test(env)
-    _assert_cc_info_has_library_to_link(env, tut, "cdylib")
+    _assert_cc_info_has_library_to_link(env, tut, "cdylib", 1)
     return analysistest.end(env)
 
 def _staticlib_provides_cc_info_test_impl(ctx):
     env = analysistest.begin(ctx)
     tut = analysistest.target_under_test(env)
-    _assert_cc_info_has_library_to_link(env, tut, "staticlib")
+    _assert_cc_info_has_library_to_link(env, tut, "staticlib", 1)
     return analysistest.end(env)
 
 rlib_provides_cc_info_test = analysistest.make(_rlib_provides_cc_info_test_impl)